Snowman

#include "colors.inc"

#declare Snow = texture
{
 pigment { color White }
 finish { ambient 0.4 }
}

#declare Coal = sphere
{
 <0,0,0>,0.05
 pigment { color Black }
}

#declare Sm_Coal = object { Coal scale 0.8 }

#declare Snowman = union
{
 sphere { <0,0.4,-16.5>,1 texture { Snow }} //Body
 union //Head
 {
  sphere { <0,1.5,-16.65>,0.5 texture { Snow }}
  union //Eyes
  {
   object { Coal translate <-0.125,1.65,-17.09> }
   object { Coal translate <0.125,1.65,-17.09> }
  }
  cone { <0,1.5,-17.15>,0.06, <0.2,1.5,-17.35>,0 pigment { color Orange }} //Nose
  union //Mouth
  {
   object { Sm_Coal translate <-0.125,1.4,-17.09> }
   object { Sm_Coal translate <0.125,1.4,-17.09> }
   object { Sm_Coal scale 0.9 translate <0,1.33,-17.09> }
   object { Sm_Coal translate <-0.0625,1.3625,-17.09> }
   object { Sm_Coal translate <0.0625,1.3625,-17.09> }
  }
 }
 union //Hat
 {
  cylinder { <0,1.8,-16.65>,<0,1.85,-16.65>,0.55 pigment { color Black }}
  cylinder { <0,1.85,-16.65>,<0,2.25,-16.65>,0.4 pigment { color Black }}
  cylinder { <0,1.9,-16.65>,<0,1.97,-16.65>,0.42 pigment { color Red }}
 }
 union //Buttons
 {
  object { Coal translate <0,0.3,-17.5> }
  object { Coal translate <0,0.6,-17.46> }
  object { Coal translate <0,0.9,-17.37> }
 }
 union //Scarf
 {
  cylinder { <0,1.1,-16.65>,<0,1.25,-16.65>,0.51}
  cone { <0,1.25,-17.15>,0,<-0.2,0.9,-17.2>,0.15}
  cone { <0,1.25,-17.15>,0,<0.2,0.9,-17.2>,0.15}
  pigment { color Red }
 }
}

camera
{
 location <0,1,-20>
 look_at <0,0.7,0>
}

light_source
{
 <-30,10,-50>
 color White
}

sky_sphere
{
 pigment { color rgb <0.0000, 0.5412, 0.6824> }
 pigment
 {
  bozo
  turbulence 0.5
  octaves 3
  lambda 6.0
  color_map
  {
        [0.0 color rgbf <1, 1, 1, 1>]
        [0.8 color rgb <0.737, 0.788, 0.820>]
        [1.0 color rgb <1, 1, 1>]
  }
  scale 0.35
  rotate y*20
 }
}

plane
{
 y,0
 texture { Snow normal { bumps 0.3 } finish { ambient 0.6 diffuse 0.4 } }
}

object { Snowman }

CategoryArtistic