Can Crusher

//Can Crusher Model
//Small Product Design Final GCSE Project
//James Kermode 9/2/1998

#include "colors.inc"
#include "woods.inc"
#include "finish.inc"
#include "metals.inc"

background { color White }

camera
{
 location <30,17,-40>
 look_at <0,17,0>
}

light_source { <0,15,-70> color White }
light_source { <20,15,0> color White }

//Back plate
difference
{
 box { <0,0,0>,<10,34,1.5> }
 box { <-0.5,-0.5,-0.5>,<1,6.5,2> }
 box { <9,-0.5,-0.5>,<10.5,6.5,2> }
 texture {T_Wood10 scale 10 rotate x*90}
}

//Sliders
#declare Slider = difference
{
 box { <0,0,0>,<2,25,3> }
 box { <1.5,-0.5,-0.5>,<2,25.5,3> }
 texture {T_Wood3 scale 10 rotate x*90}
}

object { Slider translate <0,9,-3>}
object { Slider rotate y*180 translate <10,9,0> }

//Base plate
union
{
 box { <0,6.5,-4>,<10,9,0> }
 box { <1,6.5,-9>,<9,9,-4> }
 cylinder { <9,6.5,-4>,<9,9,-4>,1 }
 cylinder { <1,6.5,-4>,<1,9,-4>,1 }
 box { <2,6.5,-10>,<8,9,-9> }
 cylinder { <8,6.5,-9>,<8,9,-9>,1 }
 cylinder { <2,6.5,-9>,<2,9,-9>,1 }
 texture { T_Wood3 finish { Shiny } scale 20 rotate x*20}
}

//Triangular Brackets
#declare Bracket = prism
{
 0,1.2,4
 <0,0>,<8,0>,<8,-5.1>,<0,0>
 texture { T_Wood3 finish { Shiny } scale 20 rotate x*20 }
}

object { Bracket rotate <270,270,0> translate <2.5,6,-7>}
object { Bracket rotate <270,270,0> translate <7.5,6,-7>}

//Crush Head
union
{
 cylinder { <5,23.5,-5>,<5,26,-5>,3.5 }
 box { <0.1,23.5,-5>,<9.9,26,0>}
 cylinder { <0.6,23.5,-5>,<0.6,26,-5>,0.5 }
 cylinder { <9.4,23.5,-5>,<9.4,26,-5>,0.5 }
 texture { T_Wood3 scale 20 rotate x*40 }
}
union
{
 cylinder { <5,23.1,-5>,<5,23.5,-5>,3.5 }
 box { <0.09,23.1,-5>,<9.89,23.1,0>}
 texture { T_Chrome_4A }
}

//Levers:

//Up-Down Lever
#declare UpDownLever = box
{
 <0,15,-7>,<0.5,25,-5.5>
 texture {T_Wood13 scale 10 rotate x*90}
}

object { UpDownLever translate x*1 }
object { UpDownLever translate x*9 }

//Angled Lever
#declare AngledLever = box
{
 <0,10,-1.5>,<0.5,35,0>
 rotate x*-18.5
 texture {T_Wood13 scale 10 rotate x*90}
}

object { AngledLever translate x*0.5}
object { AngledLever translate x*10 }

//Handle
cylinder
{
 <0.5,32.75,-11>,<9.5,32.75,-11>,1
 texture {T_Wood10 scale 10 rotate x*90}
}

//Bolts in Levers
#declare Bolt = cylinder
{
 <0,16.5,-6.25>,<1,16.5,-6.25>,0.25
 texture { T_Chrome_4A }
}

object { Bolt translate x*0.25 }
object { Bolt translate x*9.75 }

CategoryArtistic